#!/bin/csh -f

#@(#)News with uqwk in SOUP file. Jos den Bekker josdb@xs4all.nl
# $Id$

set workdir=/tmp/uqwk.$$
set polldir=~/poll
set date=`date +%d%m`
set args="-m +n +x +L -H$workdir -B0"
set prg=`basename $0`
set nonomatch

if ( ! -d $polldir ) then
  set polldir=~
endif

if ( -d $workdir ) then
  echo "${prg}: working directory $workdir already exists."
  exit 1
else
  mkdir $workdir
  if ( $status != 0 ) then
    echo "${prg}: error creating working directory $workdir"
    exit 1
  else
    cd $workdir
  endif
endif

if ( -e ~/.newsrc ) then
  cp ~/.newsrc ~/.newsrc.prev
  cp ~/.newsrc $workdir
else
  echo "${prg}: .newsrc does not exist; aborting"
  cd
  rm -rf $workdir
  exit 1
endif

uqwk $args >/dev/null
if ( $status != 0 ) then
  echo "${prg}: uqwk error"
  cd
  rm -rf $workdir
  exit 1
endif

zip -mbqj /tmp news$date AREAS *.MSG
if ( $status != 0 ) then
  echo "${prg}: zip error; output uqwk is in $workdir"
  cp $workdir/.newsrc $home
  exit 1
endif

if ( -e $polldir/news*.zip.* ) rm $polldir/news*.zip.*

if ( -e $polldir/news$date.zip ) mv $polldir/news$date.zip $polldir/news$date.zip.$$

mv news$date.zip $polldir
if ( $status != 0 ) then
  echo "${prg}: error moving $workdir/news$date.zip to $polldir
  cp $workdir/.newsrc $home
  exit 1
endif

cp $workdir/.newsrc $home
cd
rm -rf $workdir
