WORMS Game for Texas Instruments TI-82 Graphics Calculator.
Copyright  Thomas Sahlin 1997

To type in the game on your calculator, press the following buttons:
PRGM > > ENTER W O R M S ENTER
This brings you to the program editor. For information on how it
works, consult your TI-82 manual.
Now type in the following (the STO> button is represented as ->):

:0->Xmin:0->Ymin
:94->Xmax:62->Ymax
:1->Xscl:1->Yscl
:AxesOff
:0->L
:Lbl L
:ClrDraw
:L+1->L
:Text(28,36,"LEVEL")
:Text(28,60,L)
:For(A,0,700)
:End
:For(A,28,57)
:Text(A,36,"LEVEL")
:Text(A,60,L)
:End
:Text(0,0,"WORMS")
:Text(0,28,"(C)")
:Text(0,42,"THOMAS")
:Text(0,72,"SAHLIN")
:Horizontal 2
:Text(57,12,"TI-82")
:Text(57,69,"YOU")
:Text(57,36,"LEVEL")
:Text(57,60,L)
:Line(0,6,94,6)
:Line(0,6,0,55)
:Line(0,55,94,55)
:Line(94,55,94,6)
:Line(19,10,19,14)
:Line(74,10,74,14)
:If L=2
:Circle(47,31,15)
:If L=3
:Line(10,31,84,31)
:If L=4:Then
:Line(10,10,40,40)
:Line(84,10,54,40)
:End
:If L=5:Then
:Line(16,18,36,38)
:Line(22,18,42,38)
:Line(77,18,57,38)
:Line(71,18,51,38)
:End
:If L=6:Then
:Line(18,15,18,25)
:Line(20,15,20,23)
:Line(19,25,30,25)
:Line(21,23,28,23)
:Line(28,22,28,7)
:Line(30,24,30,8)
:Line(73,15,73,23)
:Line(75,15,75,25)
:Line(74,25,63,25)
:Line(72,23,65,23)
:Line(63,24,63,8)
:Line(65,22,65,7)
:End
:47->A:19->B
:-1->C:0->D
:47->E:74->F
:-1->G:0->H
:Pxl-On(E,F)
:round(rand*50,0)->I
:If I<4
:Goto D
:Lbl E
:If pxl-Test(A+C,B+D)
:Goto B
:Lbl C
:A+C->A:B+D->B
:Pxl-On(A,B)
:getKey->I
:If I>0
:Goto F
:Lbl G
:E+G->E:F+H->F
:If pxl-Test(E,F)
:Goto H
:Goto A
:Lbl F
:If I=24 and H=/1:Then                     ! =/ - Not like
:0->G:-1->H
:Goto G
:End
:If I=26 and H=/-1:Then
:0->G:1->H
:Goto G
:End
:If I=25 and G=/1:Then
:-1->G:0->H
:Goto G
:End
:If I=34 and G=/-1:Then
:1->G:0->H
:Goto G
:End
:Goto G
:Lbl D
:If I=0:Then
:1->D:0->C
:End
:If I=1:Then
:1->C:0->D
:End
:If I=2:Then
:0->C:-1->D
:End
:If I=3:Then
:-1->C:0->D
:End
:Goto E
:Lbl B
:If pxl-Test(A,B+1)=0:Then
:0->C:1->D
:Goto C
:End
:If pxl-Test(A,B-1)=0:Then
:0->C:-1->D
:Goto C
:End
:If pxl-Test(A-1,B)=0:Then
:-1->C:0->D
:Goto C
:End
:If pxl-Test(A+1,B)=0:Then
:1->C:0->D
:Goto C
:End
:Goto L
:Lbl H
:Text(28,29,"GAME")
:Text(28,51,"OVER")
:For(A,1,700)
:End
:For(A,0,30)
:Horizontal A
:Horizontal 62-A
:End
:For(A,0,47)
:Pxl-On(31,A)
:Pxl-On(31,94-A)
:End
:ClrDraw
:Disp

Now press:
2nd QUIT PRGM
select WORMS from the list
and press ENTER

You will now start at level one.
Control your worm with the arrow keys and try not to run into anything.
When you lose, the message "GAME OVER" will be displayed and you'll
soon be back in the main window.
You can break the game at any time by pressing 2nd OFF.

That's it! Enjoy!