;DISPLAY LIST INTERRUPT SERVICE ROUTINE
	.OPT NO EJECT
;
	*= 1664 	;UPPER HALF PAGE 6
;
BAK	= 53272 	;BACKGROUND COLOR REGISTER
LUM	= 53271 	;LUMINANCE COLOR REGISTER
WSYNC	= 54282 	;WAIT FOR SYNC
SETVB	= $E45C
JMPEND	= $E462
	PHA  	;SAVE A REGISTER
	TXA 
	PHA  	;SAVE X REGISTER
	LDX COUNT 	;VALUE OF LINE ON SCREEN
	LDA COLTAB,X
	STA WSYNC 	;WAIT FOR SYNC
	STA BAK
	LDA LUMTAB,X
	STA LUM
	INC COUNT
	PLA 
	TAX  	;RESTORE X
	PLA  	;RESTORE A
	RTI  	;RETURN FROM INTERRUPT
COUNT	.BYTE 1
;
;VERTICAL BLANK INTERRUPT ROUTINE
;
	PLA  	;REMOVE ARGUMENT COUNT FROM STACK
	LDA #7 	;DEFERRED MODE
	LDY #VBI&$FF 	;ADDRESS OF THE
	LDX #VBI/256 	;VBI ROUTINE
	JSR SETVB
	RTS 
VBI	LDA #1
	STA COUNT
	JMP JMPEND
;
;COLOR AND LUMINANCE TABLES
COLTAB	.BYTE $94,$94,$94,$94,$94,$94,$94,$94
	.BYTE $94,$94,$94,$94,$94,$94,$94,$94
	.BYTE $94,$94,$94,$94,$94,$94,$94,$94
LUMTAB	.BYTE $0A,$0A,$0A,$0A,$0A,$0A,$0A,$0A
	.BYTE $0A,$0A,$0A,$0A,$0A,$0A,$0A,$0A
	.BYTE $0A,$0A,$0A,$0A,$0A,$0A,$0A,$0A
	.END 
