PMSCROLL
BASE2	= 176*256 	;set CHset adr.
C1	= 704 	;Color
S1	= 53256 	;Size P1
S5	= 53260 	;SIze Missile
H1	= 53248 	;HPOSP0
H2	= H1+1
H3	= H2+1
H4	= H3+1
H5	= H4+1
H6	= H5+1
H7	= H6+1
H8	= H7+1
PM0	= BASE2+768
PM1	= PM0+256
PM2	= PM1+256
PM3	= PM2+256
PM4	= PM3+256
CH	= 57344 	;STARTING AT 'A'
LEN	= ENDTEXT-TEXT
; -------------------
	JSR CLEAR
	LDA #176
	STA 54279
	LDA #3
	STA 53277
	LDA #62
	STA 559
	LDA #1
	STA 623
	LDA #158
	STA C1
	STA C1+1
	STA C1+7
	LDA #30
	STA C1+2
	STA C1+3
	LDA #176 	;HOR. POS.
	STA H1
	LDA #144
	STA H2
	LDA #112
	STA H3
	LDA #80
	STA H4
	LDA #72
	STA H5
	LDA #64
	STA H6
	LDA #56
	STA H7
	LDA #48
	STA H8
	LDA #3 	;SIZES
	STA S1
	STA S1+1
	STA S1+2
	STA S1+3
	LDA #255
	STA S5
	LDA # <TEXT
	STA 203
	LDA # >TEXT
	STA 204
;-----------------
GTEXT	LDA # <CH
	STA 205
	LDA # >CH
	STA 206
	LDA #0
	STA 208
	LDY #0 	;GET CHAR
	LDA (203),Y
	CMP #32
	BNE CHAR.NOT.FOUND
	JSR LONGDELAY
	JSR LONGDELAY
	JMP BACK.FROM.LDELAY
CHAR.NOT.FOUND
	ASL A
	ASL A
	ASL A
	ROL 208
	ADC 205
	STA 205
	LDA 206
	LSR 208
	ADC #0
	STA 206
BACK.FROM.LDELAY
	INC 203
	BNE MAIN
	INC 204
;-------------------
MAIN	LDY #0
	LDX #0
L4	LDA (205),Y
	STA SPACE,X
	STA SPACE+1,X
	STA SPACE+2,X
	INY 
	INX 
	INX 
	INX 
	CPX #24
	BNE L4
;-------------------
SCROLL	LDY #7
L8	JSR DELAY
	LDX #0
L9	ASL SPACE,X
	ROL PM1+217,X 	;(+60) sets
	ROL PM2+217,X 	;the vertical
	ROL PM3+217,X 	;position
	ROL PM4+217,X 	;
	ROL PM0+217,X 	;
	INX 
	CPX #24
	BNE L9
	DEY 
	BNE L8
	INC LENLO
	BNE AAA
	INC LENHI
AAA	LDA LENHI
	CMP #LEN/256
	BNE BBB
	LDA LENLO
	CMP #LEN&255
	BNE BBB
	JMP PMSCROLL
BBB	JMP GTEXT
TEXT	.SBYTE "            HI THERE RICKY @ THIS SMALL DEMO IS A PART FROM THE DEMO DISK THAT THE "
	.SBYTE "ISRAEL ATARI CRAZY TEAM IS GOING TO RELESE SOON!        THIS PART IN'T FINISHED YET, "
	.SBYTE "THERE ARE THINGS TO ADD,     SO JUST WAIT FOR THE IACT DEMO DISK IT'S GOING TO BE GOOD!!!"
	.SBYTE "              WELL, I RAN OUT OF THINGS TO WRITE, SO UNTILL NEXT TIME  BYE!!! AND SHALOM "
	.SBYTE "FROM ISRAEL.........................            "
ENDTEXT
SPACE	.BYTE "!!!!!!!!!!!!!!!!!!!!!!!!"	;!!!!!!!! SPECIAL CHARS !!!!!!!!
;----------------------
CLEAR	LDA # <BASE2
	STA 203
	LDA # >BASE2
	STA 204
	LDX #8
	LDA #0
LL1	LDY #0
LL2	STA (203),Y
	DEY 
	BNE LL2
	INC 204
	DEX 
	BNE LL1
	RTS 
;----------------------
DELAY	LDA #11
	STA 212
LO1	LDA #216
	STA 213
LO	DEC 213
	BNE LO
	DEC 212
	BNE LO1
	RTS 
	RTS 
LONGDELAY	LDA #255
	STA 212
LLO1	LDA #255
	STA 213
LLO	DEC 213
	BNE LLO
	DEC 212
	BNE LLO1
	RTS 
LENHI	.BYTE 0
LENLO	.BYTE 0
